aws-waf/cloudwatch.tf at main · TheSoftwareHouse/aws-waf · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
locals {
  managed_rules = { for rule in var.aws_managed_rule_groups : rule.name => rule }

  rules_with_alarm_configuration = {
    for key, value in merge(var.ip_set_rules, var.ip_rate_based_rules, var.geo_match_rules, local.managed_rules) : key
    => {
      rule_name                = key
      rule_alarm_configuration = value.alarm_configuration

      alarm_dimension = value.action == "block" ? "BlockedRequests" : "CountedRequests"
    } if value.alarm_configuration != null
  }
}

resource "aws_cloudwatch_log_group" "waf_log_group" {
  count = var.cloudwatch.enable_logging ? 1 : 0
  name  = "aws-waf-logs-${var.name}"

  retention_in_days = 14

  lifecycle {
    create_before_destroy = false
  }
}

resource "aws_cloudwatch_dashboard" "waf_dashboard" {
  count          = var.cloudwatch.enable_logging && var.cloudwatch.enable_dashboard ? 1 : 0
  dashboard_name = var.name
  dashboard_body = templatefile("${path.module}/templates/cw_dashboard.json", {
    webacl_name           = aws_wafv2_web_acl.main.name
    webacl_log_group_name = one(aws_cloudwatch_log_group.waf_log_group[*].name)
    aws_region            = data.aws_region.current.name
  })

  lifecycle {
    create_before_destroy = false
  }
}

resource "aws_cloudwatch_metric_alarm" "cw_rule_alarms" {
  for_each = local.rules_with_alarm_configuration

  alarm_name = "${var.name}-${each.value.rule_name}-alarm"

  comparison_operator = "GreaterThanThreshold"
  evaluation_periods  = 1
  metric_name         = each.value.alarm_dimension
  namespace           = "AWS/WAFV2"

  period             = each.value.rule_alarm_configuration.observation_period
  threshold          = each.value.rule_alarm_configuration.threshold
  statistic          = "Sum"
  treat_missing_data = "notBreaching"

  dimensions = merge(
    var.scope == "REGIONAL" ? { Region = data.aws_region.current.name } : {},
    {
      Rule   = each.value.rule_name
      WebACL = aws_wafv2_web_acl.main.name
    }
  )

  alarm_actions = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []
  ok_actions    = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []

  tags = var.tags
}

resource "aws_cloudwatch_metric_alarm" "allowed_requests_alarm" {
  count = var.allowed_requests_alarm_configuration != null ? 1 : 0

  alarm_name = "${var.name}-allowed-requests-alarm"

  comparison_operator = "GreaterThanThreshold"
  evaluation_periods  = 1
  metric_name         = "AllowedRequests"
  namespace           = "AWS/WAFV2"

  period             = var.allowed_requests_alarm_configuration.observation_period
  threshold          = var.allowed_requests_alarm_configuration.threshold
  statistic          = "Sum"
  treat_missing_data = "notBreaching"

  dimensions = merge(
    var.scope == "REGIONAL" ? { Region = data.aws_region.current.name } : {},
    {
      WebACL = aws_wafv2_web_acl.main.name
    }
  )

  alarm_actions = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []
  ok_actions    = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []

  tags = var.tags
}

resource "aws_cloudwatch_metric_alarm" "blocked_requests_alarm" {
  count = var.blocked_requests_alarm_configuration != null ? 1 : 0

  alarm_name = "${var.name}-blocked-requests-alarm"

  comparison_operator = "GreaterThanThreshold"
  evaluation_periods  = 1
  metric_name         = "BlockedRequests"
  namespace           = "AWS/WAFV2"

  period             = var.blocked_requests_alarm_configuration.observation_period
  threshold          = var.blocked_requests_alarm_configuration.threshold
  statistic          = "Sum"
  treat_missing_data = "notBreaching"

  dimensions = merge(
    var.scope == "REGIONAL" ? { Region = data.aws_region.current.name } : {},
    {
      WebACL = aws_wafv2_web_acl.main.name
    }
  )

  alarm_actions = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []
  ok_actions    = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []

  tags = var.tags
}

resource "aws_cloudwatch_metric_alarm" "counted_requests_alarm" {
  count = var.counted_requests_alarm_configuration != null ? 1 : 0

  alarm_name = "${var.name}-counted-requests-alarm"

  comparison_operator = "GreaterThanThreshold"
  evaluation_periods  = 1
  metric_name         = "CountedRequests"
  namespace           = "AWS/WAFV2"

  period             = var.counted_requests_alarm_configuration.observation_period
  threshold          = var.counted_requests_alarm_configuration.threshold
  statistic          = "Sum"
  treat_missing_data = "notBreaching"

  dimensions = merge(
    var.scope == "REGIONAL" ? { Region = data.aws_region.current.name } : {},
    {
      WebACL = aws_wafv2_web_acl.main.name
    }
  )

  alarm_actions = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []
  ok_actions    = var.enable_cloudwatch_notifications_to_slack ? [one(aws_sns_topic.waf_cloudwatch_notifications[*].arn)] : []

  tags = var.tags
}