txObj and rxObj non working with Arduino Nano and ESP32-S3

[SteriCraft]

Describe the bug
Sender: Arduino Nano programmed with Arduino IDE (library installed via the Library manager).
Receiver; ESP32-S3 based touch-screen (this one) (library installed by adding "PowerBroker2/SerialTransfer" in platformio.ini)
Library version used: 3.1.5

txObj and rxObj don't work. This line:
transfer.txObj(val, sizeof(val));
fails to copy data into the buffer.

It's the same problem on the ESP32-S3 side.
It seems that txObj writes zeros to txBuff.

Verified by reading packet.txBuff immediately after txObj. All bytes were 0x00.
Same for rxBuff and rxObj.

To Reproduce
Simply try to send and receive a primitive-type integer, such as:
uint32_t val = 42;

Expected behavior
rxObj should be stuffed with the received data on the receiver end.

Workaround
I used memcpy on both sides to get the data to flow:
On the sender side:

memcpy(m_transfer.packet.txBuff, &val, sizeof(val));
m_transfer.sendData(sizeof(val));

On the receiver side:

uint8_t result = m_transfer.available();

if (result)
{
    uint32_t val;
    memcpy(&val, m_transfer.packet.rxBuff, sizeof(val));
    Serial.println(val);
}

[PowerBroker2]

Idk, I did a loopback test on one of my Teensy 4.1 boards using the latest release of SerialTransfer from the libraries manager and it worked as expected:

#include "SerialTransfer.h"


SerialTransfer myTransfer;

struct __attribute__((packed)) STRUCT {
  char z;
  float y;
} txStruct, rxStruct;

char txarr[] = "hello";
char rxarr[] = "        ";

enum Status {
    TX,
    RX
} state = Status::TX;


void setup()
{
  Serial.begin(115200);
  Serial1.begin(115200);
  myTransfer.begin(Serial1);

  txStruct.z = '$';
  txStruct.y = 4.5;
}


void loop()
{
  switch (state)
  {
    case Status::TX:
    {
      // use this variable to keep track of how many
      // bytes we're stuffing in the transmit buffer
      uint16_t sendSize = 0;
    
      ///////////////////////////////////////// Stuff buffer with struct
      sendSize = myTransfer.txObj(txStruct, sendSize);
    
      ///////////////////////////////////////// Stuff buffer with array
      sendSize = myTransfer.txObj(txarr, sendSize);
    
      ///////////////////////////////////////// Send buffer
      myTransfer.sendData(sendSize);

      state = Status::RX;
      
      break; // Exits the switch structure
    }
    case Status::RX:
    {
      if(myTransfer.available())
      {
        // use this variable to keep track of how many
        // bytes we've processed from the receive buffer
        uint16_t recSize = 0;
    
        recSize = myTransfer.rxObj(rxStruct, recSize);
        Serial.print(rxStruct.z);
        Serial.print(rxStruct.y);
        Serial.print(" | ");
    
        recSize = myTransfer.rxObj(rxarr, recSize);
        Serial.println(rxarr);
        
        state = Status::TX;
      }
      
      delay(500);
      break;
    }
    default:
    {
      break;
    }
  }
}

[PowerBroker2]